OCLUA_OPEN

Initialize the Lua engine.

01 luastate USAGE POINTER.

CALL "OCLUA_OPEN" RETURNING luastate END-CALL

OCLUA_STACK

Check and possibly resize the Lua data stack. Returns 0 if Lua cannot expand the stack to the requested size.

01 elements USAGE BINARY-LONG VALUE 32.
01 result   USAGE BINARY-LONG.

CALL "OCLUA_STACK"
    USING
        BY VALUE luastate
        BY VALUE elements
    RETURNING result
END-CALL

OCLUA_DOSTRING

Evaluate a null terminated alphanumeric field as a Lua program producing any top of stack entry and returning the depth of stack after evaluation.

Takes a luastate, a null terminated command string, a result field and length and returns an integer depth.

01 luacommand pic x(64).
01 luaresult  pic x(32).
01 depth      usage binary-long.

move 'return "OpenCOBOL " .. 1.0 + 0.1' & x"00" to luacommand
call "OCLUA_DOSTRING"
    using
        by value luastate
        by reference luacommand
        by reference luaresult
        by value function length(luaresult)
    returning depth
end-call
display
    "OpenCOBOL displays: " depth " |" luaresult "|"
end-display

Outputs:

OpenCOBOL displays: +0000000001 |OpenCOBOL 1.1                   |

OCLUA_DOFILE

Evaluate a script using a null terminated alphanumeric field naming a Lua program source file, retrieving any top of stack entry and returning the depth of stack after evaluation.

Takes a luastate, a null terminated filename, a result field and length and returns an integer depth.

01 luascript  pic x(10) value 'oclua.lua' & x"00".
01 luaresult  pic x(32).

call "OCLUA_DOFILE"
    using
        by value luastate
        by reference luascript
        by reference luaresult
        by value function length(luaresult)
    returning depth
end-call
display
    "OpenCOBOL displays: " depth " |" luaresult "|"
end-display

Given oclua.lua:

-- Start
-- Script: oclua.lua
print("Lua prints hello")

hello = "Hello OpenCOBOL from Lua"
return math.pi, hello
-- End

Outputs:

Lua prints hello
OpenCOBOL displays: +0000000002 |Hello OpenCOBOL from Lua        |

and on return from Lua, there is math.pi and the Hello string remaining on the Lua state stack.

OCLUA_DEPTH

Returns the current number of elements on the Lua stack.

call "OCLUA_DEPTH"
    using
        by value luastate
    returning depth
end-call
display "Lua depth: " depth end-display

OCLUA_GET

Retrieves values from the Lua stack, returning the length of the retrieved item.

An example that populates and displays an OpenCOBOL table:

01 items                pic 9 usage computational-5.
01 luastack.
   03 luaitem           pic x(32) occurs 5 times.

perform varying items from 1 by 1
    until items > depth
        call "OCLUA_GET"
            using
                by value luastate
                by value items
                by reference luaresult
                by value function length(luaresult)
            returning lualength
        end-call
        move luaresult to luaitem(items)
end-perform

perform varying items from 1 by 1
    until items > depth
        display
           "Item " items ": " luaitem(items)
        end-display
end-perform

Lua numbers the indexes of stacked items from 1, first item to n, last item (current top of stack). Negative indexes may also be used as documented by Lua, -1 being top of stack.

Sample output:

Item 1: OpenCOBOL 1.1
Item 2: 3.1415926535898
Item 3: Hello OpenCOBOL from Lua
Item 4: 3.1415926535898
Item 5: Hello OpenCOBOL from Lua

OCLUA_POP

Pops the given number of elements off of the Lua stack returning the depth of the stack after the pop.

Example that empties the Lua stack:

call "OCLUA_POP"
    using
        by value luastate
        by value depth
    returning depth
end-call

OCLUA_CLOSE

Close and free the Lua engine.

call "OCLUA_CLOSE" using by value luastate end-call